**3.60. Шаблоны сообщений**

Подсистема «Шаблоны сообщений» позволяет экономить время, создавая письма и сообщения SMS по заранее подготовленным шаблоном. В тексте шаблонов сообщений можно определить реквизиты, которые будут заполняться данными из документов или справочников программы. Кроме того, в шаблоне можно указать, что к письму нужно прикреплять вложения и печатные формы.

Подсистема «Шаблоны сообщений» работает совместно с подсистемами «[Работа с почтовыми сообщениями](https://its.1c.ru/db/content/bsp301doc/src/3.48.%20работа%20с%20почтовыми%20сообщениями.htm?_=1542292879#_работа_с_почтовыми)», «[Отправка SMS](https://its.1c.ru/db/content/bsp301doc/src/3.60.%20%D1%88%D0%B0%D0%B1%D0%BB%D0%BE%D0%BD%D1%8B%20%D1%81%D0%BE%D0%BE%D0%B1%D1%89%D0%B5%D0%BD%D0%B8%D0%B9.htm?_=1542292879#_отправка_sms_1)», а также «[Взаимодействия](https://its.1c.ru/db/content/bsp301doc/src/3.10.%20взаимодействия.htm?_=1542292879#_взаимодействия)». Если какой-либо из перечисленных подсистем нет в составе конфигурации, то соответствующая функциональность шаблонов писем или SMS автоматически скрывается из интерфейса.

**Настройка**

Для того чтобы пользователи имели возможность создавать шаблоны сообщение на основании документов или справочников, необходимо принять решение по поводу состава типов таких объектов (определить предметы шаблонов сообщений). Например, это могут быть документы счетов на оплату, справочники контрагентов, сотрудников и т.п.

● Затем выбранные объекты перечислить в свойстве Тип определяемого типа ПредметШаблонаСообщения;

● во всех модулях менеджеров этих объектов добавить следующие процедуры и при необходимости, вписать их реализацию:

// СтандартныеПодсистемы.ШаблоныСообщений

// Вызывается при подготовке шаблонов сообщений и позволяет переопределить список реквизитов и вложений.

//

// Параметры:

//  Реквизиты               - ДеревоЗначений - список реквизитов шаблона.

//         \*\* Имя            - Строка - Уникальное имя общего реквизита.

//         \*\* Представление  - Строка - Представление общего реквизита.

//         \*\* Тип            - Тип    - Тип реквизита. По умолчанию строка.

//         \*\* Формат         - Строка - Формат вывода значения для чисел, дат, строк и булевых значений.

//  Вложения                - ТаблицаЗначений - печатные формы и вложения

//         \*\* Имя            - Строка - Уникальное имя вложения.

//         \*\* Представление  - Строка - Представление варианта.

//         \*\* ТипФайла       - Строка - Тип вложения, который соответствует расширению файла: "pdf", "png", "jpg", mxl" и др.

//  ДополнительныеПараметры - Структура - дополнительные сведения о шаблоне сообщений.

//

Процедура ПриПодготовкеШаблонаСообщения(Реквизиты, Вложения, ДополнительныеПараметры) Экспорт

КонецПроцедуры

// Вызывается в момент создания сообщений по шаблону для заполнения значений реквизитов и вложений.

//

// Параметры:

//  Сообщение - Структура - структура с ключами:

//    \* ЗначенияРеквизитов - Соответствие - список используемых в шаблоне реквизитов.

//      \*\* Ключ     - Строка - имя реквизита в шаблоне;

//      \*\* Значение - Строка - значение заполнения в шаблоне.

//    \* ЗначенияОбщихРеквизитов - Соответствие - список используемых в шаблоне общих реквизитов.

//      \*\* Ключ     - Строка - имя реквизита в шаблоне;

//      \*\* Значение - Строка - значение заполнения в шаблоне.

//    \* Вложения - Соответствие - значения реквизитов

//      \*\* Ключ     - Строка - имя вложения в шаблоне;

//      \*\* Значение - ДвоичныеДанные, Строка - двоичные данные или адрес во временном хранилище вложения.

//  ПредметСообщения - ЛюбаяСсылка - ссылка на объект являющийся источником данных.

//  ДополнительныеПараметры - Структура -  Дополнительная информация о шаблоне сообщения.

//

Процедура ПриФормированииСообщения(Сообщение, ПредметСообщения, ДополнительныеПараметры) Экспорт

КонецПроцедуры

// Заполняет список получателей SMS при отправке сообщения сформированного по шаблону.

//

// Параметры:

//   ПолучателиSMS - ТаблицаЗначений - список получается SMS.

//     \* НомерТелефона - Строка - номер телефона, куда будет отправлено сообщение SMS.

//     \* Представление - Строка - представление получателя сообщения SMS.

//     \* Контакт       - Произвольный - контакт, которому принадлежит номер телефона.

//  ПредметСообщения - ЛюбаяСсылка, Структура - ссылка на объект являющийся источником данных, либо структура,

//    \* Предмет               - ЛюбаяСсылка - ссылка на объект являющийся источником данных

//    \* ПроизвольныеПараметры - Соответствие - заполненный список произвольных параметров.//

//

Процедура ПриЗаполненииТелефоновПолучателейВСообщении(ПолучателиSMS, ПредметСообщения) Экспорт

КонецПроцедуры

// Заполняет список получателей письма при отправки сообщения сформированного по шаблону.

//

// Параметры:

//   ПолучателиПисьма - ТаблицаЗначений - список получается письма.

//     \* Адрес           - Строка - адрес электронной почты получателя.

//     \* Представление   - Строка - представление получается письма.

//     \* Контакт         - Произвольный - контакт, которому принадлежит адрес электрнной почты.

//  ПредметСообщения - ЛюбаяСсылка, Структура - ссылка на объект являющийся источником данных, либо структура,

//                                              если шаблон содержит произвольные параметры:

//    \* Предмет               - ЛюбаяСсылка - ссылка на объект являющийся источником данных

//    \* ПроизвольныеПараметры - Соответствие - заполненный список произвольных параметров.

//

Процедура ПриЗаполненииПочтыПолучателейВСообщении(ПолучателиПисьма, ПредметСообщения) Экспорт

КонецПроцедуры

// Конец СтандартныеПодсистемы.ШаблоныСообщений

● Если код процедур оставить незаполненными, то в шаблонах сообщений будут доступны реквизиты предмета  и определенные в нем печатные формы. При наличии у предмета контактной информации список адресатов будет заполнен, в противном случае он будет пустой.

● Пример реализации этих процедур см. в демонстрационной конфигурации в справочнике \_ДемоФизическиеЛица.

**Размещение в командном интерфейсе**

Для использования подсистемы необходимо разместить в командном интерфейсе ответственного за список шаблонов сообщений справочник ШаблоныСообщений – для ведения списка шаблонов сообщений.

В случае если в конфигурации не используется подсистема «[Настройки программы](https://its.1c.ru/db/content/bsp301doc/src/3.29.%20настройки%20программы.htm?_=1542292879#_настройки_программы)», в рабочем месте администратора программы необходимо разместить справочник ШаблоныСообщений и константу ИспользоватьШаблоныСообщений – для включения и выключения подсистемы. См. пример в форме Органайзер обработки ПанельАдминистрированияБСП.

**Особые случаи внедрения подсистемы**

● [Внедрение подсистемы «Шаблоны сообщений» без подсистемы «Управление доступом».](https://its.1c.ru/db/content/bsp301doc/src/3.63.%20особые%20случаи%20внедрения%20подсистем.htm?_=1542292879#_внедрение_подсистемы_«шаблоны)

● [Внедрение подсистемы «Шаблоны сообщений» без подсистемы «Работа с файлами».](https://its.1c.ru/db/content/bsp301doc/src/3.63.%20особые%20случаи%20внедрения%20подсистем.htm?_=1542292879#_внедрение_подсистемы_«шаблоны_1)

**Настройка прав доступа пользователей**

Для настройки прав доступа пользователей к данным подсистемы «Шаблоны сообщений» следует использовать роли, приведенные ниже.

Таблица 3.120.

| № | Роли и их назначение |
| --- | --- |
| 1. | ДобавлениеИзменениеЛичныхШаблоновСообщений  Добавление и изменение персональных шаблонов сообщений  (доступных только автору).  Просмотр и использование общих шаблонов сообщений (доступных всем пользователям). |
| 2. | ДобавлениеИзменениеШаблоновСообщений  Подготовка общих шаблонов сообщений. Добавление и изменение шаблонов сообщений.  Администрирование списка шаблонов сообщений. |
| 3. | ЧтениеШаблоновСообщений  Аудит шаблонов сообщений.  Просмотр любых шаблонов сообщений без права изменения и использования. |
| 4. | ПолныеПрава (из подсистемы «Базовая функциональность»).  Включение и отключение использования подсистемы «Шаблонов сообщений». Удаление помеченных на удаление объектов подсистемы. |

Пример настройки прав доступа пользователей:

Таблица 3.121.

| № | Группа пользователей и ее функции | Состав ролей |
| --- | --- | --- |
| 1. | Ответственный за список шаблонов сообщений | ● БазовыеПраваБСП (из подсистемы «Базовая функциональность»),  ● ДобавлениеИзменениеШаблоновСообщений |

**Использование при разработке конфигурации**

По умолчанию в шаблонах сообщений доступны все реквизиты предмета сообщения, за исключением реквизитов с типом ХранилищеЗначения и некоторых стандартных реквизитов (ПометкаУдаления, ЭтоГруппа и др.). Также доступны поля контактной информации и доп. реквизиты и сведения. В качестве вложений к письмам доступны определенные в конфигурации печатные формы, внешние печатные формы и печатные формы из расширений. При наличии контактной информации у предмета будет заполонен список адресатов: для почтовых сообщений из полей с видом контактной информации электронная почта, а для сообщений SMS с видом контактной информации телефон.

В случаях, когда при создании шаблонов сообщений недостаточно стандартных средств, можно предусмотреть собственные реквизиты, печатные формы и вложения

1.  В процедуре ПриПодготовкеШаблонаСообщения определить состав используемых реквизитов и вложений:

НовыйРеквизит = Реквизиты.Добавить();

НовыйРеквизит.Имя = "СостояниеКонтрагента";

НовыйРеквизит.Представление = НСтр("ru = 'Состояние контрагента'");

НовыйРеквизит.Тип = Новый ОписаниеТипов("Строка");

Карта = Вложения.Добавить();

КартинкаКнопки.Имя = "КартаРасположенияОфиса'";

КартинкаКнопки.Представление = НСтр("ru = Карта расположения офиса'");

КартинкаКнопки.ТипФайла = "jpg";

2. В процедуре ПриФормированииСообщения заполнить ранее определенные реквизиты и вложения:

Сообщение.ЗначенияРеквизитов["СостояниеКонтрагента"] = ПроверкаКонтрагентов.СостояниеКонтрагента(ПредметСообщения.ИНН, ПредметСообщения.КПП);

АдресКартинкиВоВременноеХранилище = КартаРасположенияОфис();

Сообщение.Вложения["КартаРасположенияОфиса"] = АдресКартинкиВоВременноеХранилище;

3. Если у предмета нет контактной информации или требуется особенный список адресатов, то список получателей письма или сообщений SMS  должен быть заполен по контактной информации реквизита предмета или используя собственный алгоритм. Для этого в модуле менеджера объекта, являющимся предметом шаблонов сообщений, требуется. В этом случае в процедурах ПриЗаполненииТелефоновПолучателейВСообщении и ПриЗаполненииПочтыПолучателейВСообщении заполнить получателей сообщения:

Процедура ПриЗаполненииПочтыПолучателейВСообщении(ПолучателиПисьма, ПредметСообщения) Экспорт

ШаблоныСообщений.ЗаполнитьПолучателей(ПолучателиПисьма, ПредметСообщения, "Контрагент");

Получатель = ПолучателиПисьма.Добавить();

Получатель.Адрес = ПредметСообщения.ЭлектроннаяПочтаСтрокой;

Получатель.Представление = ПредметСообщения.ЭлектроннаяПочтаПредставление;

КонецПроцедуры

Процедура ПриЗаполненииТелефоновПолучателейВСообщении(ПолучателиSMS, ПредметСообщения) Экспорт

ШаблоныСообщений.ЗаполнитьПолучателей(ПолучателиSMS, ПредметСообщения, "Контрагент", Перечисления.ТипыКонтактнойИнформации.Телефон);

КонецПроцедуры

Пример использования см. в документе \_ДемоСчетНаОплатуПокупателю и справочнике \_ДемоКонтрагенты демонстрационной конфигурации.

В тех случаях, когда требуется определить список реквизитов, вложений или список получателей сразу для всех или нескольких предметов шаблонов сообщений, то необходимо размещать код в одноименных процедурах общего модуля ШаблоныСообщенийПереопределяемый.

**Разработка предметов шаблонов сообщений, не привязанных к объектам конфигурации.**

В случаях, когда необходимо создать назначение для шаблонов сообщений, которое не является объектом конфигурации, то в процедуре ПриОпределенииНастроек общего модуля ШаблоныСообщенийПереопределяемый необходимо добавить код, например:

Предмет = Настройки.ПредметыШаблонов.Добавить();

Предмет.Имя = "ОповещениеКлиентаИзменениеЗаказа";

Предмет.Представление = НСтр("ru = 'Оповещение клиента ""Изменение заказа""'");

Затем для возможности выбора нужного шаблона в форме создать реквизит c  типом СправочникСсылка.ШаблоныСообщений и в свойстве ПараметрыВыбора элемента формы (поля ввода) связанного с реквизитом указать параметры отбора:

● Отбор.Назначение – Строка, имя или представление созданого назначения;

● Отбор.ПредназначенДляЭлектронныхПисем или Отбор.ПредназначенДляSMS – Булево, в зависимости от необходимого вида шаблона сообщения.

Пример использования таких назначений см. в документе \_ДемоЗаказПокупателя демонстрационной конфигурации.

**Добавление общих реквизитов предметов шаблонов сообщений**

Помимо реквизитов, специфичных для конкретного предмета шаблона сообщений, предусмотрена возможность определять реквизиты, общие для всех предметов. Например, для того чтобы сделать доступным для выбора реквизит Основная организация во всех шаблонах сообщений, необходимо описать общий реквизит в общем модуле ШаблоныСообщенийПереопределяемый в процедуре ПриОпределенииНастроек:

НовыйРеквизит = Настройки.ОбщиеРеквизиты.Строки.Добавить();

НовыйРеквизит.Имя = "ОсновнаяОрганизация";

НовыйРеквизит.Представление = НСтр("ru = 'Основная организация'");

НовыйРеквизит.Тип = Тип("СправочникСсылка.\_ДемоОрганизации");

Заполнение общих реквизитов производится в общем модуле ШаблоныСообщенийПереопределяемый в процедуре ПриФормированииСообщения аналогично другим реквизитам.

**Программная отправка писем и сообщений SMS по шаблонам с дополнительным отбором**

Для интерактивной отправки писем и сообщений SMS по шаблонам предназначена процедура СформироватьСообщение общего модуля ШаблоныСообщенийКлиент. При этом с ее помощью дополнительно можно ограничить список выбора доступных шаблонов, указав предмет и/или владельца шаблонов.

Например, если шаблоны писем должны различаться не только в зависимости от выбранной организации, но и от ее подразделения, то следует предварительно:

● включить справочник Организации в свойство Тип определяемого типа ПредметШаблонаСообщения;

● в свойстве Тип определяемого типа ВладелецШаблонаСообщения указать справочник Подразделения;

Затем для отправки письма по шаблону вызвать:

ПараметрыСообщения = Новый Структура(...); // параметры письма

ШаблоныСообщенийКлиент.СформироватьСообщение(Организация, "Письмо",, ПодразделениеОрганизации, ПараметрыСообщения);

Подробнее см. комментарий к процедуре СформироватьСообщение общего модуля ШаблоныСообщенийКлиент, а также пример в демонстрационной конфигурации в форме элемента справочника \_ДемоПроекты.

**Настройка обмена данными**

Все объекты метаданных подсистемы, содержащие данные, рекомендуется включать в планы обмена распределенной ИБ (РИБ).